#This script is for display of GCN4, a yeast transcription 
#factor containing a basic region leucine zipper (bZIP) DNA-binding motif.
#From the structure determined by Ellenberger et al., 1992, Cell 71, pp.
# 1223-1237.  Rasmol commands by Hannah Chen, Jmol by Jason Kahn.
#If molecule isn't loaded...
#zap
#load GCN4-1.pdb
#Script starts here:
define g_major (G and (*.N7 or *.O6 or *.C5 or *.C6 or *.C8 or *.H8))
define a_major (A and (*.N6 or *.N7 or *.C5 or *.C6 or *.2H6 or *.C8 or *.H8)) 
define t_major (T and (*.C5 or *.O4 or *.C4 or *.C5M or *.1H5M or *.2H5M or *.3H5M))
define c_major (C and (*.C5 or *.N4 or *.C4 or *.1H4 or *.2H4 or *.H5))
define g_minor (G and (*.N3 or *.C4 or *.C2 or *.N2 or *.1H2 or *.2H2))
define a_minor (A and (*.N3 or *.C4 or *.C2 or *.H2))
define c_minor (C and (*.C2 or *.O2))
define t_minor (T and (*.C2 or *.O2))
define major_groove (g_major or a_major or c_major or t_major)
define minor_groove (g_minor or a_minor or c_minor or t_minor)

#---------------------------------------------------------------------------
#GCN4's basic region of a helix is anchored in the major groove (colored red),
#you can rotate to see more clearly.
select all
labels off
spacefill off
cartoons off
monitors off
set monitors off
color cpk
select all
hbonds calculate
color hbonds green
hbonds 0.30
wireframe 50
#
select protein
ribbon on
color orange
wireframe off
select DNA
backbone 200
color backbone cyan
wireframe 150
select major_groove
color red
select minor_groove
color violet
select DNA and (not major_groove) and (not minor_groove)
color cpk
#
reset
rotate z -113
rotate y 2
rotate x -177
set echo top
echo
set echo bottom
echo GCN4-DNA Cocrystal