# 
# Script for display of 1lmb.pdb, the lambda repressor at 1.8 A, from
# Beamer and Pabo, 1992, JMB 227, 177-196.  
# By Jason Kahn, UMCP
# If you haven't loaded the molecule yet:
#zap
#load 1lmb.pdb
#
set ambient 60
set specular on
#set shadows on  # not implemented in jmol, crashes applet
#
reset
zoom 90
rotate y 220
rotate x 40
rotate z 105
rotate x -20
#
define halfdna (dna and (resno>10 and resno<32))
define halfall (halfdna or (resno<61 and :4))
define g_major (G and (*.N7 or *.O6 or *.C5 or *.C6 or *.C8 or *.H8))
define a_major (A and (*.N6 or *.N7 or *.C5 or *.C6 or *.C8 or *.H8)) 
define t_major (T and (*.C5 or *.O4 or *.C4 or *.C5M))
define c_major (C and (*.C5 or *.N4 or *.C4 or *.H5))
define u_major (u and (*.C5 or *.O4 or *.C4 or *.H5))
define major_groove (g_major or a_major or c_major or t_major or u_major)
define g_minor (G and (*.N3 or *.C4 or *.C2 or *.N2))
define a_minor (A and (*.N3 or *.C4 or *.C2 or *.H2))
define c_minor (C and (*.C2 or *.O2))
define t_minor (T and (*.C2 or *.O2))
define u_minor (u and (*.C2 or *.O2))
define minor_groove (g_minor or a_minor or c_minor or t_minor or u_minor)
#
select all
labels off
spacefill off
cartoons off
monitors off
set monitors off
color cpk
select all
hbonds calculate
color hbonds green
hbonds 0.30
wireframe 50
#
select dna
wireframe 150
backbone 200
color cpk
color backbone pink
#
select protein
hbonds off
backbone off
#
set echo top
echo
set echo bottom
echo Lambda Repressor-DNA Cocrystal