# Script for display of 1cdw.pdb, the human TBP+DNA co-complex, from
# Nikolov et al., 1997, PNAS vol. 93, pp 4862-4867. 
# Rasmol commands by Jason Kahn, UMCP
# If you haven't loaded the molecule yet:
#zap
#load 1cdw.pdb
reset
slab off
set ambient 60
set specular on
set shadows on
wireframe 50
spacefill off
color cpk
# This gives a "standard" view of the complex
zoom 120
rotate z -178
rotate y -51
rotate x 100
translate x 2
translate y -7
#
# Focus on DNA-binding beta sheet face, the "saddle"
#
select protein
backbone 100  
wireframe 50
color [150,100,100]
cartoons
color backbone [100,100,100]
color cartoons [100,100,100]
select protein and sheet
cartoons 350
color cartoons blue
color backbone blue
select protein and not sheet and not helix
backbone 120
select ser155 and *.CA
set fontsize 16
label "N-term"
select lys333 and *.CA
label "C-term"
#
# Emphasize DNA in the complex
#
select dna
color cpk
backbone 250
color backbone red
wireframe 150
#
# Now rotate around as desired...
#
# This view showcases the B-DNA entering one end of the complex:
reset
zoom 120
rotate z 176
rotate y -49
rotate x 52
translate x 2
translate y -7
#
# Look at the largely hydrophobic DNA-binding surface of the protein
# Note that rasmol colors residue by residue, not atom by atom --
# (The DNA is in front, barely visible)
#
reset
zoom 120
rotate z -175
rotate y -41
rotate x 26
translate x 2
translate y -7
select dna
wireframe 
select sheet and hydrophobic
color [100,100,100]
select sheet and polar
color green
select sheet and negative
color blue
select sheet and positive 
color red
select sheet
spacefill
#
# Now look at DNA grooves to emphasize unwinding and splaying
# out of the minor groove
#
define g_major (G and (*.N7 or *.O6 or *.C5 or *.C6 or *.C8 or *.H8))
define a_major (A and (*.N6 or *.N7 or *.C5 or *.C6 or *.2H6 or *.C8 or *.H8)) 
define t_major (T and (*.C5 or *.O4 or *.C4 or *.C5M or *.1H5M or *.2H5M or *.3H5M))
define c_major (C and (*.C5 or *.N4 or *.C4 or *.1H4 or *.2H4 or *.H5))
define major_groove (g_major or a_major or c_major or t_major)
define g_minor (G and (*.N3 or *.C4 or *.C2 or *.N2 or *.1H2 or *.2H2))
define a_minor (A and (*.N3 or *.C4 or *.C2 or *.H2))
define c_minor (C and (*.C2 or *.O2))
define t_minor (T and (*.C2 or *.O2))
define minor_groove (g_minor or a_minor or c_minor or t_minor)
#
select protein
color [100,100,100]
spacefill off
wireframe off
select dna
wireframe 350
backbone off
select major_groove
color [0,100,0]
select minor_groove 
color orange
reset
rotate z 143
rotate y -27
rotate x 147
translate x 2
translate y -7
zoom 120
#
# Spin the molecule around to follow the grooves
#
# Look at phe intercalation at the "stirrups"
#
select all
wireframe 50
reset
rotate z -178
rotate y -51
rotate x 100
translate x 2
translate y -7
zoom 120
select a112 or t111 or t5 or a6
spacefill
color cpk
select g12 or c105 or a11 or t106
spacefill
color cpk
select phe284,phe301,phe210,phe193 
color green
wireframe 300
select dna
wireframe 100 
backbone off
#
# Zoom in on one intercalation site
#
restrict ((dna and (resno<9 or resno>108)) or (protein and (resno>272 and resno<305))) 
select (dna and (resno<9 or resno>108))
hbonds
color hbonds cyan
hbonds 40
reset
zoom 180
rotate z 175
rotate y -36
rotate x 52
translate x -25
translate y -24
center atomno=1020
select a112,t111,t5,a6             
spacefill 250
select (a112,t111,t5,a6) and backbone
spacefill off
select phe284,phe301
wireframe 200